CMake 的基本使用

2019年5月7日 214次阅读 来源: 农大鲁迅

准备工作

  • 最新版的 CMake（3.8）。
  • C/C++ 编译器（GCC，MSVC，clang）。
  • 编辑器（CLion，Vim，Sublime Text）。

Hello World

  • 建立一个 CMakeDemo 文件夹，作为项目的根文件夹。
  • 新建一个主文件 main.cpp
#include <iostream>

int main() {
    std::cout << "Hello, World!" << std::endl;
    return 0;
}
  • 在文件夹内新建一个 CMakeLists.txt 文件
cmake_minimum_required(VERSION 3.8)
project(CMakeDemo)

set(CMAKE_CXX_STANDARD 11)

set(SOURCE_FILES main.cpp)
add_executable(Demo ${SOURCE_FILES})

第一行代表运行此项目需要的 CMake 最小版本为 3.8，第二行为项目名，第三行和第四行的 set 表示设置一个变量，括号里的第一个值为 key，后续的值为 value，最后一行表示添加一个可执行文件。
在 bash 中输入以下命令。

cmake .
make

第一行表示生成 Makefile 文件，第二行代表编译。
输入 ./Demo，运行结果

Hello, World!

这是一个简单的 demo，下面开始正式的内容。

标准 C++ 工程的目录结构

通常的，一个 C++ 项目包含以下几个目录：

  • 源代码目录
  • 第三方库的包含目录
  • 第三方库的库目录
  • 文档目录
  • 二进制目录
  • README 和 License 等

所以我们在 CMakeDemo 的根目录新建一个 src 文件夹，用来放置源码，将 main.cpp 移入其中，并新建一个 CMakeLists.txt。

CMakeDemo
└─src
|  └─main.cpp
|  └─CMakeLists.txt
└─CMakeLists.txt

我们在 CMakeDemo/src/CMakeLists.txt 写入如下内容

add_executable(Demo main.cpp)

将 CMakeDemo/CMakeLists.txt 的内容修改为

cmake_minimum_required(VERSION 3.8)
project(CMakeDemo)

set(CMAKE_CXX_STANDARD 11)

add_subdirectory(src bin)

add_subdirectory 表示生成一个子目录，src 是目录名，bin 是生成二进制的位置（可缺省）。
我们采用 out-of-source 外部构建，即将编译后的文件与源代码分离。所以在 CMakeDemo 文件夹下新建一个 build 文件夹，并 cd 进入（即当前的文件夹位置为 CMakeDemo/build），在 bash 中输入

cmake ..
make

可以看到在 build/bin 目录下，生成了二进制文件。

动态链接库

将 src 目录的下的内容删除，新建 hello.h 和 hello.cpp，内容如下：

hello.h

#ifndef CMAKEDEMO_HELLO_H
#define CMAKEDEMO_HELLO_H

#ifdef __cplusplus
extern "C" {
#endif

void say(const char *str);

#ifdef __cplusplus
}
#endif

#endif //CMAKEDEMO_HELLO_H

hello.cpp

#include <cstdio>
#include "hello.h"

void say(const char *str) {
    printf("%s\n", str);
}

修改 src/CMakeLists.txt 为

set(LIBHELLO hello.cpp hello.h)

add_library(hello_static STATIC ${LIBHELLO})
add_library(hello SHARED ${LIBHELLO})
set_target_properties(hello PROPERTIES LINKER_LANGUAGE C)

add_library 表示生成一个库，SHARED 表示生成的是动态库，STATIC 表示生成的是静态库，在这里我们全部选择。最后一行为设置目标参数 LINKER_LANGUAGE C 表示 C 语言导出。

修改 CMakeDemo/CMakeLists.txt 为

cmake_minimum_required(VERSION 3.8)
project(CMakeDemo)

set(CMAKE_CXX_STANDARD 11)

add_subdirectory(src lib)

即将输出文件夹命名为 lib。

在项目根目录下新建一个 build 文件，按照上节的方式编译，可以看到，在 lib 目录生成了 libhello.so 和 libhello_static.a 两个库文件。

调用共享库

按照如下目录建立文件

CMakeDemo
└─src
|  └─CMakeLists.txt
|  └─hello
|    └─CMakeLists.txt
|    └─hello.h
|    └─hello.cpp
|  └─demo
|    └─CMakeLists.txt
|    └─demo.cpp
└─CMakeLists.txt

按照规范，我们应为每个文件夹建立一个 CMakeLists.txt。src/hello 是我们的主项目，src/demo 是一个需要调用前者的 demo，下面填写代码

  • CMakeDemo/CMakeLists.txt
cmake_minimum_required(VERSION 3.8)
project(CMakeDemo)

set(CMAKE_CXX_STANDARD 11)

add_subdirectory(src)
  • src/CMakeLists.txt
include_directories(hello)

add_subdirectory(demo bin)
add_subdirectory(hello lib)
  • src/demo/CMakeLists.txt
add_executable(hellodemo demo.cpp)
target_link_libraries(hellodemo hello)
  • src/demo/demo.cpp
#include <hello.h>
#include <cstdio>

int main()
{
    const char *p = "Hello";
    say(p);
    printf("Done\n");
    return 0;
}
  • src/hello 目录的内容不变

按照上一节的方式编译，可以在 build/src/bin 目录中找到 demo 文件，在 build/src/lib 中找到共享库文件。
运行 demo 文件

***@ubuntu:~/CMakeDemo/build/src/bin$ ./hellodemo
Hello
Done

使用外部共享库

一般情况下，我们习惯将第三方包的头文件放到 include 目录下，库文件放到 lib 目录下。所以我们将 CMakeDemo 文件夹备份，然后清空，按照如下结构建立文件

CMakeDemo
├── CMakeLists.txt
├── include
│   └── hello
│       ├── CMakeLists.txt
│       ├── hello.cpp
│       └── hello.h
├── lib
│   └── libhello.so
└── src
    ├── CMakeLists.txt
    └── main.cpp

将原文件中的 hello 目录直接拷贝到 include 目录，上一步生成的共享库 libhello.so 拷贝到 lib 文件夹下。

  • CMakeDemo/CMakeLists.txt
cmake_minimum_required(VERSION 3.8)
project(CMakeDemo)

set(CMAKE_CXX_STANDARD 11)

include_directories(include)
link_directories(lib)

add_subdirectory(src bin)
  • CMakeDemo/src/CMakeLists.txt
add_executable(main main.cpp)
target_link_libraries(main hello)
  • CMakeDemo/src/main.cpp
#include <hello/hello.h>
#include <cstdio>

int main()
{
    const char *p = "Hello";
    say(p);
    printf("Done\n");
    return 0;
}

编译，运行

***@ubuntu:~/CMakeDemo/bin$ ./main
Hello
Done

其他常用操作

添加 OpenMP 支持

IF (APPLE)
    message(STATUS "clang does not support OpenMP!")
ELSEIF (WIN32 OR UNIX)
    find_package(OpenMP REQUIRED)
    IF(OPENMP_FOUND)
        message(STATUS "OPENMP FOUND!")
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${OpenMP_C_FLAGS}")
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OpenMP_CXX_FLAGS}")
        set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${OpenMP_EXE_LINKER_FLAGS}")
    ENDIF()
ENDIF ()
    原文作者：农大鲁迅
    原文地址: https://www.jianshu.com/p/a5bb1db05967
    本文转自网络文章，转载此文章仅为分享知识，如有侵权，请联系博主进行删除。
点赞