vba – 预期的错误只能是440 /自动化错误？

2023年2月12日 233次阅读

上下文

我在VBA中写了一个小的unit testing library,所以我可以写这样的单元测试：

'@ExpectedError()
Public Sub TestCannotRegisterLoggerTwice()

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    LogManager.Register logger
    LogManager.Register logger

End Sub

以上测试通过：

2014-10-04 16:42:55 TestCannotRegisterLoggerTwice: [PASS]

如果我删除ExpectedError“属性”,它将失败：

2014-10-04 16:43:49 TestCannotRegisterLoggerTwice: [INCONCLUSIVE] - Test raised an error: Automation error

到现在为止还挺好.好吧,差不多.

测试中的错误工作正常！

现在如果我让测试将除法归零,就像这样：

'@ExpectedError()
Public Sub TestCannotRegisterLoggerTwice()

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    Dim boom As Integer
    boom = 1 / 0

    LogManager.Register logger
    LogManager.Register logger

End Sub

测试仍然没有结果,但这次错误被正确选取：

2014-10-04 16:45:12 TestCannotRegisterLoggerTwice: [INCONCLUSIVE] - Test raised an error: Division by zero

我不明白的部分是,在两种情况下,错误都是在同一个VBAProject中引发的 – 前者在一个名为LogManager(SUT)的类中,后者在一个名为LogManagerTests的类中.

这是抛出我正在测试的预期错误的部分：

Public Sub Register(ByVal logger As ILogger)
    If Not this.Loggers.Exists(logger.Name) Then
        this.Loggers.Add logger.Name, logger
    Else
        Err.Raise LogManagerError.DuplicateLoggerError, "LogManager.Register", "There is already a logger registered with name '" & logger.Name & "'."
    End If
End Sub

我想要的是

我希望能够使用’@ExpectedError(-2147220406)(LogManagerError.DuplicateLoggerError的长表示)来装饰我的测试方法,并且能够在TestEngine.ReflectTestMethods方法中清除此部分：

For Each prospect In classMethods

    If CanAddTestMethod(prospect, result) Then

        Set tMethod = New TestMethod
        Set tMethod.OwnerInstance = classInstance
        tMethod.MethodName = prospect.name

        If prospect.HasAttribute(ExpectedErrorAttribute) Then
            If prospect.AttributeParameters(ExpectedErrorAttribute).Count <> 0 Then
                Err.Raise vbObjectError + 1055, "TestEngine.ReflectTestMethods", "ExpectedErrorAttribute for test method '" & prospect.name & "' should not have parameters."
            End If

            'force an "Automation Error" to be expected, 
            'because VBA "eats" the expected error thrown in the SUT:
            tMethod.ExpectedError = 440 ' prospect.AttributeParameters(ExpectedErrorAttribute).First

        End If

        result.Add tMethod.MethodName, tMethod

    End If

Next

是这样吗？我只能指望SUT抛出自动化错误？

我试过的东西

由于错误是在实际测试方法中引发时正确报告的,我试过这个：

'@ExpectedError()
Public Sub TestCannotRegisterLoggerTwice()

    On Error GoTo CleanFail

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    LogManager.Register logger
    LogManager.Register logger

    Exit Sub

CleanFail:

    Dim errNumber As Long
    errNumber = Err.Number

    Dim errSource As String
    errSource = Err.Source

    Dim errDescription As String
    errDescription = Err.Description

    Err.Raise errNumber, errSource, errDescription
End Sub

但即使errDescription包含正确/预期的错误消息,测试库仍会收到编号为440的自动化错误.

为什么我的测试库正确地将除法除以零,而不是自定义错误？

编辑：经过进一步的实验,我注意到我可以成功“预期”任何内置错误,所以这有效：

'@ExpectedError(5)
Public Sub TestCannotRegisterLoggerTwice()

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    LogManager.Register logger
    LogManager.Register logger

End Sub

…提供更改我的TestEngine代码以接受@ExpectedError属性的参数,并且我在SUT中引发错误#5 /“无效的过程调用或参数”,而不是自定义错误;我也无法提供自定义错误消息.这并不理想,因为它强制SUT只抛出内置错误,而我的测试库不能假设它是这种情况.

VBA中的自定义错误代码有什么特别之处？

最佳答案 我不知道VBA中的自定义错误代码有什么特别之处.

但是,如果SUT中抛出的错误号不是推荐的vbObjectError n的形式(可以从您期望的错误代码的-2147220406表示中推断出来),那么任何应用程序定义的或对象定义的错误都可以使用,并“预期”：

Public Enum LogManagerError
    DuplicateLoggerError = 100
    LoggerNotRegisteredError
End Enum

TestEngine仍然不会“看到”自定义错误消息,但现在您可以这样做：

'@ExpectedError(100)
Public Sub TestCannotRegisterLoggerTwice()

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    LogManager.Register logger
    LogManager.Register logger

End Sub

得到这个结果：

2014-10-04 18:09:56 TestCannotRegisterLoggerTwice: [PASS]

如果删除了ExpectedError属性,则会收到应用程序定义或对象定义的错误：

2014-10-04 18:10:20 TestCannotRegisterLoggerTwice: [INCONCLUSIVE] - Test raised an error: Application-defined or object-defined error

这在技术上是正确的 – 被授予,能够在测试结果中报告自定义错误消息会很好,但这只是必须处理的那些限制之一.

至少你现在可以在SUT中抛出不同的错误,并能够判断是否引发了错误 – 这是在这里实现的目标.

同时,自定义错误消息仍然可见,并以“正常”代码显示：

'@ExpectedError(100)
Public Sub TestCannotRegisterLoggerTwice()

    On Error GoTo CleanFail

    Dim logger As ILogger
    Set logger = MockLogger.Create("TestLogger", TraceLevel)

    LogManager.Register logger
    LogManager.Register logger

    Exit Sub
CleanFail:
    MsgBox Err.Description
    Err.Raise Err.Number

End Sub

2014-10-04 18:21:24 TestCannotRegisterLoggerTwice: [PASS]
点赞