在groovy shell中使用groovy类

我正在使用Groovy类别在一些DSL下工作,我想找到一种方法来使用我的DSL与groovy
shell,而无需为每个命令明确地使用(MyCategory){myObject.doSomething()}.

例如,假设我有以下玩具类别:

class MyCategory {
    static Integer plus(Integer integer, String string){
        return integer + Integer.valueOf(string)
    }
}

然后,我可以通过以下方式在groovysh中使用此类别:

groovy> use(MyCategory){ 2 + '3' } //gives 5

那么,有没有办法为所有groovysh命令全局设置MyCategory,所以没有必要每次包装我的命令(MyCategory){…}?例如:

groovy> useGlobally(MyCategory); //call something like this only once
groovy> 2 + '3' //automatically uses MyCategory and gives 5

最佳答案 该类别的想法是缩小元编程的范围.为什么不在这种情况下使用metaClass?

groovy:000> class MyCategory {
groovy:001>     static Integer plus(Integer integer, String string){
groovy:002>         return integer + Integer.valueOf(string)
groovy:003>     }
groovy:004> }
===> true
groovy:000> Integer.metaClass.mixin MyCategory
===> null
groovy:MyCategory@131fa4b> 2 + '4'
===> 6
groovy:MyCategory@131fa4b> 

更新:使用大量方法,您可以遍历静态方法的第一个参数,并将它们混合到相应的参数类型类中.

class MyCategory {
    static global() {
        MyCategory.metaClass.methods
            .findAll { it.isStatic() && !it.name.startsWith("__") && it.name != "global" }
            .each { it.nativeParameterTypes[0].mixin MyCategory }
    }

    static Integer plus(Integer integer, String string){
        return integer + Integer.valueOf(string)
    }

    static String yell(String a, times) {
      a.toUpperCase() * times + "!!!"
    }
}


MyCategory.global()


assert "a".yell(3) == "AAA!!!"
assert 2+'3' == 5
点赞