输出 – Stata表:使用esttab,使用xtreg指示()

有没有人知道是否可以在esttab中使用宏观的“indication()”选项与xtreg?

如果我运行回归之类的

eststo MYREG: reg y x i.category,

那我就能做到

esttab MYREG , indicate("Category FE = *.category")

我会像这样得到一张漂亮的桌子:

----------------------
x            2.3443
             (2.15)
Category FE    Yes
----------------------
N             4321
----------------------

问题:当我使用时

xtset category
xtreg y x 

没有系数保存,我可以在指示语句中使用.还是有吗?我一直找不到.

我意识到我可以使用

estadd local fe "Yes" : MYREG

然后我可以得到一张像这样的桌子

esttab MYREG , stats(N fe)

----------------------
x            2.3443
             (2.15)
----------------------
N             4321
Category FE    Yes
----------------------

但我正在使用一堆其他“i.VAR”类型的固定效果,我希望它们全部一起显示在系数下方,而不是只有其中一个出现在页脚中.

最佳答案 最快的方法是使用varlist选项插入任意行text / smcl / latex.例如,要在_cons之前插入注意FE的行(而不是在stats面板中向下),请使用

esttab myreg, stats(N) varlabels(,blist(_cons "{p2col 0 20 0 0: FE}yes{p_end}"))

哪个会显示:

----------------------------
                      (1)   
                   weight   
----------------------------
week                6.210***
                 (158.97)   
FE                 yes
_cons               19.36***
                  (32.09)   
----------------------------
N                     432   
----------------------------
t statistics in parentheses
* p<0.05, ** p<0.01, *** p<0.001

您可以调整20以获得正确的水平布局,或者只使用空格(如果您拥有多个模型,则可以执行此操作.

如果你想要更强大的东西(可以处理模型重新排序),另一种方法是编辑每个模型估计并在e(b)(和e(V))矩阵中输入假条目,然后在输出时使用指示表.这是我用过的一个简单的ado:

*Needs erepost
program add_fake_coeff_to_e, eclass
    args cname cval

    tempname eb eb2 eV eV2
    mat `eb' = e(b)
    local eb_names : colnames `eb'
    mat `eb2' = `eb', `cval'
    matrix colnames `eb2' = `eb_names' `cname'

    *Need the dimensions of V to match b
    mat `eV' = e(V)
    local num_eb : word count `eb_names'

    mat `eV2' = I(`=`num_eb'+1')
    mat `eV2'[1,1] = `eV'
    matrix colnames `eV2' = `eb_names' `cname'
    matrix rownames `eV2' = `eb_names' `cname'

    erepost b=`eb2' V=`eV2'
end

那么你会这样做

reg blah
add_fake_coeff_to_e "FE" 1
estimates store est1
esttab est1 , <other opts> indicate("FE", labels("Y" ""))
点赞