excel-vba – Excel VBA – 工作簿之间的.Find方法

2023年9月11日 498次阅读

题：

为什么Range.Find方法在引用不同的工作簿时不起作用？

问题：
我正在尝试在工作簿之间复制数据,但Range.Find方法正在以“运行时错误1004”停止.我在Windows 7计算机上使用Excel 2007.

细节：
在两个工作簿上,每个工作簿仅引用或使用Sheet1.我有一个程序(ztest),其中包含以下概述：

>格式化工作表
>遍历工作簿#1的E列中的所有单元格
>使用Range.Find方法,在工作簿#2的E列中查找值
>找到后,设置工作簿#1偏移列=工作簿#2偏移列

我想用.Find做这个 – 不使用HLOOKUP等.

我在某种程度上简化了代码,以缩小实际情况.这不显示上面的步骤4,但是在包含.Find方法的语句中,错误发生在步骤3中：

Public Sub ztest2()
'set workbook titles
Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"
Dim cl As Variant

With Workbooks(w2).Worksheets(1)
  'format the sheet
  .Range("A1", "D1").EntireColumn.Hidden = True
  'loop through all cells column E of workbook #1
  For Each cl In .Range("E2", Cells(Rows.Count, "E").End(xlUp))
    'find value of current cell in column E, workbook #2
    Workbooks(w1).Worksheets(1) _
    .Range("E2", Cells(Rows.Count, "E").End(xlUp)) _
    .Find(what:=cl.Value, LookIn:=xlValues).Select
  Next
End With

End Sub

最佳答案 非常重要的是,您要非常好地构建代码,以便理解它没有任何困难.如果需要,请编写额外的代码行,这样即使您在6个月后看到代码,也可以确定代码的作用.同样完全限定您的对象.

试试这个(UNTESTED).我评论了代码.因此,如果您不理解某些内容,请回复

Const w1 As String = "05AR 20130920.xlsx"
Const w2 As String = "05AR 20130923.xlsx"

Sub ztest2()
    Dim wb1 As Workbook, wb2 As Workbook
    Dim ws1 As Worksheet, ws2 As Worksheet
    Dim cl As Range, ws1Rng As Range, ws2Rng As Range, aCell as Range
    Dim lRowW1 As Long, lRowW2 As Long

    '~~> Define your workbook and worksheets here
    Set wb1 = Workbooks(w1)
    Set ws1 = wb1.Sheets(1)
    Set wb2 = Workbooks(w2)
    Set ws2 = wb2.Sheets(1)

    '~~> Work with First workbook to get last row and define your range
    With ws1
        lRowW1 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws1Rng = .Range("E2:E" & lRowW1)
    End With

    '~~> Work with Second workbook to get last row and define your range
    With ws2
        .Range("A1", "D1").EntireColumn.Hidden = True

        lRowW2 = .Range("E" & .Rows.Count).End(xlUp).Row
        Set ws2Rng = .Range("E2:E" & lRowW2)

        For Each cl In ws2Rng
            '~~> Do the find
            Set acell = ws1Rng.Find(what:=cl.Value, LookIn:=xlValues)

            '~~> Check if found or not. This is required else you will
            '~~> get an error if no match found
            If Not acell Is Nothing Then
                '
                '~~> Do what ever you want here
                '
            End If
        Next
    End With
End Sub
点赞