sas – 宏变量数据类型不一致

2019年7月2日 650次阅读

我正在尝试创建一个简单的宏来检查特定的宏变量是丢失还是不存在.通常,这需要两个语句：％symexist,如果确实存在,则检测其是否为空值的其他逻辑.以下代码将所有这些组合成一个.

%macro isnull(macvar);
    %sysevalf(%superq(%superq(macvar)) NE %str(), boolean);
%mend isnull;

问题

我不能在％if语句中使用％isNull(),因为返回的值似乎总是一个字符.如果它在开放代码中或在宏本身内,则此行为会有所不同.

我试过的

我把它缩小到宏不解析为数值.我已经尝试了从％sysfunc(putn())到％cmpres()到％sysfunc(compress())的所有内容.如果它在开放代码中,则为数字.如果它在另一个宏中,那就是它的特征.你可以用这段代码看到它：

/* Miss2 resolves incorrectly as character */
%macro check;
    %let miss1=%sysevalf(%superq(asdf) =, boolean);
    %let miss2=%isNull(asdf);

    %put Miss1: %datatyp(&miss1);
    %put Miss2: %datatyp(&miss2);
%mend;
%check;

/* Miss2 resolves correctly as numeric */
%let miss1=%sysevalf(%superq(asdf) =, boolean);
%let miss2=%isNull(asdf);

%put Miss1: %datatyp(&miss1);
%put Miss2: %datatyp(&miss2);

想

我希望能够在％if语句中使用它来检查宏是否同时存在且不是空白.

%macro foo;
    %if(%isNull(sysuserid) = 1) %then %put sysuserid exists;
    %if(%isNull(asdffdsa) = 0) %then %put asdffdsa does not exist;

    %if(%isNull(sysuserid) > 0) %then %put this should resolve;
    %if(%isNull(asdffdsa) > 0) %then %put this should not resolve;
%mend;
%foo;

最佳答案 你在这里遇到的问题是你的宏中有一个分号.看到这个：

174  %macro check;
175      %let miss1=%sysevalf(%superq(asdf) NE %str(), boolean);
176      %let miss2=%missm(asdf);
177
178      %put &miss1. Miss1: %datatyp(&miss1);
179      %put &miss2. Miss2: %datatyp(%unquote(&miss2));
180  %mend;
181  %check;
WARNING: Apparent symbolic reference ASDF not resolved.
WARNING: Apparent symbolic reference ASDF not resolved.
0 Miss1: NUMERIC
0; Miss2: CHAR

注意;？编译它代替：

%macro missm(macvar);
    %sysevalf(%superq(%superq(macvar)) NE %str(), boolean)
%mend missm;

你得到：

185  %macro check;
186      %let miss1=%sysevalf(%superq(asdf) NE %str(), boolean);
187      %let miss2=%missm(asdf);
188
189      %put &miss1. Miss1: %datatyp(&miss1);
190      %put &miss2. Miss2: %datatyp(%unquote(&miss2));
191  %mend;
192  %check;
WARNING: Apparent symbolic reference ASDF not resolved.
WARNING: Apparent symbolic reference ASDF not resolved.
0 Miss1: NUMERIC
0 Miss2: NUMERIC

我还要补充一点,我认为你不应该跳过％symexist.您可以在日志中以此处的方式收到警告,这很容易避免.

%macro missm(macvar);
  %if %symexist(&macvar.) %then
    %sysevalf(%superq(%superq(macvar)) NE , boolean)
  %else
    0 
%mend missm;

您还会注意到我删除了不必要的％str(),它实际上没有做任何事情.请参阅Chang Chung的开创性论文Is This Macro Parameter Blank,了解原因(如果您还没有阅读过,可以获得一些更好的信息).

最后 – 我想我会建议重命名宏和/或反转方向. ％if％missm对我说’如果这个宏变量丢失’,这与你所说的相反：如果它没有丢失则返回TRUE. ％missm应该为EQ [blank]或NOT％symexist返回true;它应该为[已定义且包含值]返回false.

点赞