如何在Log4perl中记录两个不同的文件？

2023年4月23日 328次阅读

我有一个Perl脚本,可以生成两个不同的数据流.

我需要将它们记录到两个单独的日志文件中.

我知道有两种方法导致不同的日志文件,但在我的情况下似乎没有一种方法有用：

>使用类别(Perl模块名称).

在我的例子中,流都是在相同的代码中生成的(“主”包,但这是无关紧要的,重要的是字面上我有彼此相邻的代码行记录到2个不能分成不同Perl的位置模块).
>使用不同的日志级别.

但是,两者都应以相同的优先级记录(例如,两者都记录了info()调用和error())因此我不能使用FAQ配方logging WARN/ERROR to different files.

最佳答案 Log4perl中的 Categories是任意的,与应用程序的类层次结构无关.

use strict;
use warnings;

use Log::Log4perl qw(get_logger);

my $conf = q(
log4perl.category.first  = DEBUG, FileAppender1
log4perl.category.second = DEBUG, FileAppender2

log4perl.appender.FileAppender1          = Log::Log4perl::Appender::File
log4perl.appender.FileAppender1.filename = first.log
log4perl.appender.FileAppender1.layout   = Log::Log4perl::Layout::SimpleLayout

log4perl.appender.FileAppender2          = Log::Log4perl::Appender::File
log4perl.appender.FileAppender2.filename = second.log
log4perl.appender.FileAppender2.layout   = Log::Log4perl::Layout::SimpleLayout
);

Log::Log4perl::init(\$conf);

my $logger1 = get_logger('first');
my $logger2 = get_logger('second');

$logger1->debug('foo');
$logger2->info('bar');
$logger1->error('baz');

first.log

DEBUG - foo
ERROR - baz

second.log

INFO - bar
点赞