cl-mongo用法入门

2023年11月28日 253次阅读 来源: Liutos

最近用Common Lisp开发一个个人项目，需要记录发出的HTTP请求的参数，包括了目标地址、HTTP body，以及HTTP头部等多种信息。为了可以结构化地存储这些数据（比如HTTP头部是由多个键值对组成的），我选择将它们保存到MongoDB中。Google一番后，我找到了cl-mongo这个库，可以在Common Lisp中读写MongoDB，尝试了一下也确实可以满足自己的需求。为了方便自己查阅，也为了方便有相同需求的人了解如何使用cl-mongo，于是写了这篇文章。

首先使用CL-MONGO:MONGO函数连接MongoDB的服务器程序（mongod）。因为在我的系统上mongod进程监听的是27017这个端口，并且我希望使用的数据库名为test，因此键入如下代码来连接数据库

(cl-mongo:mongo :db "test"
                :host "127.0.0.1"
                :port 27017)

连接上了数据库后，首先尝试往其中写入一个文档。假设现在要记录的是发出的HTTP请求的信息，那么一个可以写入的基本信息就是请求的目标地址。假设在命令行的mongo shell中输入的内容如下

db.http_request.insert({uri: 'http://example.com'});

那么使用cl-mongo提供的DB.INSERT函数达到上述效果的代码如下

(cl-mongo:db.insert "http_request"
                    (cl-mongo:kv "uri" "http://example.com"))

求值上述代码后返回值为NIL。为了将上述写入的文档重新查询出来，需要使用cl-mongo提供的DB.FIND函数。因为只有一个文档，所以直接查询就可以查看到结果了。在mongo shell中我们可以使用如下代码查询

db.http_request.find();

使用DB.FIND函数的话编写的代码可能会长得像下面这样

(cl-mongo:db.find "http_request" :all)

在我的系统上求值了上述代码后在REPL中输出的内容如下

((86 449 0 1 8 0 0 1 "http_request")
 (<CL-MONGO:DOCUMENT> : { 
   _id : CL-MONGO::BSON-OID [#(89 52 26 160 109 156 254 71 184 115 102 30)]
   elements : 1}

))

值得注意的是，DB.FIND的返回值不完全是文档组成的数组，而是在这个结果集的数组之外又多了一层列表，并且列表的第一个元素还是一个一看之下不知其所以然的子列表。由于cl-mongo的GitHub上没有提及这个玩意儿的来历，我也没有深入去了解DB.FIND函数的实现代码，因此这个元素就先忽略它吧。如果需要使用DB.FIND查询到的结果，那么开发者需要对DB.FIND的返回值应用一下函数SECOND才行，如下

(second (cl-mongo:db.find "http_request" :all))

返回值的列表中的每一个元素都是CL-MONGO:DOCUMENT这个类的实例对象，如果要直接使用还是稍微有点不方便的，因此我写了一个函数用来将DB.FIND函数查询到的CL-MONGO:DOCUMENT的实例对象都转换为较为熟悉，容易操作的数据类型——association list，函数的定义如下

(defun document-to-alist (doc)
  "Convert a DOC of type CL-MONGO:DOCUMENT to a equivalent, serializable alist."
  (check-type doc cl-mongo:document)
  (labels ((aux (doc)
             (cond ((typep doc 'cl-mongo:document)
                    (let ((keys (cl-mongo:get-keys doc)))
                      (mapcar #'(lambda (key)
                                  (cons key
                                        (aux (cl-mongo:get-element key doc))))
                              keys)))
                   (t doc))))
    (let ((id (cl-mongo:doc-id doc)))
      (append (aux doc) (list (cons "_id" id))))))

使用如下代码即可查看方才所写入的文档究竟长什么样子了

(document-to-alist (first (second (cl-mongo:db.find "http_request" :all))))

如果想要修改数据库中的文档，例如增加一个字段，那么可以使用cl-mongo提供的DB.UPDATE函数，用法如下

(cl-mongo:db.update "http_request"
                    (cl-mongo:kv "uri" "http://example.com")
                    (cl-mongo:kv "$set"
                                 (cl-mongo:kv "method" "GET")))

最后如果要删除刚才所写入的这个文档，可以使用cl-mongo的DB.DELETE函数（我很好奇这个函数居然不是叫做DB.REMOVE），用法如下

(cl-mongo:db.delete "http_request"
                    (cl-mongo:kv "uri" "http://example.com"))
    原文作者：Liutos
    原文地址: https://www.jianshu.com/p/9d7c399f6f17
    本文转自网络文章，转载此文章仅为分享知识，如有侵权，请联系博主进行删除。
点赞