c – 使用每个实例颜色和偏移量的OpenGL实例渲染

2023年6月25日 251次阅读

您好我正在尝试使用glDraw
ArraysInstanced()渲染大量轴对齐的多维数据集.固定尺寸的每个立方体只能根据其中心位置和颜色而变化.每个立方体也只需要几种不同的颜色.因此,我希望使用以下每个实例数据来呈现数百万个多维数据集：

struct CubeInfo {
  Eigen::Vector3f center; // center of the cube (x,y,z)
  int labelId;  // label of the cube which affects its color
};

所以我使用以下顶点着色器：

#version 330

uniform mat4 mvp_matrix;

//regular vertex attributes
layout(location = 0) in vec3 vertex_position;

// Per Instance variables
layout(location = 1) in vec3 cube_center;
layout(location = 2) in int cube_label;

// color out to frag shader
out vec4 color_out;

void main(void) {
  // Add offset cube_center
  vec4 new_pos = vec4(vertex_position + cube_center, 1);
  // Calculate vertex position in screen space
  gl_Position = mvp_matrix * new_pos;

  // Set color_out based on label
  switch (cube_label) {
  case 1:
    color_out = vec4(0.5, 0.25, 0.5, 1);
    break;
  case 2:
    color_out = vec4(0.75, 0.0, 0.0, 1);
    break;
  case 3:
    color_out = vec4(0.0, 0.0, 0.5, 1);
    break;
  case 4:
    color_out = vec4(0.75, 1.0, 0.0, 1);
    break;
  default:
    color_out = vec4(0.5, 0.5, 0.5, 1); // Grey
    break;
  }
}

和相应的片段着色器：

#version 330

in vec4 color_out;
out vec4 fragColor;

void main()
{
    // Set fragment color from texture
    fragColor = color_out;
}

但是,color_out始终采用默认的灰色值,即使cube_label值介于1到4之间.这是我的问题.我在上面的着色器中做错了吗？**

我用1-4之间的随机labelIds初始化了cubeInfo vbo.所以我期待看到比以下更丰富的输出：

这是我的渲染代码,它使用了Qt的QGLShaderProgram和QGLBuffer包装器：

  // Enable back face culling
  glEnable(GL_CULL_FACE);
  cubeShaderProgram_.bind();

  // Set the vertexbuffer stuff (Simply 36 vertices for cube)
  cubeVertexBuffer_.bind();
  cubeShaderProgram_.setAttributeBuffer("vertex_position", GL_FLOAT, 0, 3, 0);
  cubeShaderProgram_.enableAttributeArray("vertex_position");
  cubeVertexBuffer_.release();

  // Set the per instance buffer stuff
  cubeInstanceBuffer_.bind();

  cubeShaderProgram_.setAttributeBuffer("cube_center", GL_FLOAT, offsetof(CubeInfo,center), 3, sizeof(CubeInfo));
  cubeShaderProgram_.enableAttributeArray("cube_center");
  int center_location = cubeShaderProgram_.attributeLocation("cube_center");
  glVertexAttribDivisor(center_location, 1);

  cubeShaderProgram_.setAttributeBuffer("cube_label", GL_INT, offsetof(CubeInfo,labelId), 1, sizeof(CubeInfo));
  cubeShaderProgram_.enableAttributeArray("cube_label");
  int label_location = cubeShaderProgram_.attributeLocation("cube_label");
  glVertexAttribDivisor(label_location, 1);

  cubeInstanceBuffer_.release();

  // Do Instanced Renering
  glDrawArraysInstanced(GL_TRIANGLES, 0, 36, displayed_num_cubes_ );

  cubeShaderProgram_.disableAttributeArray("vertex_position");
  cubeShaderProgram_.disableAttributeArray("cube_center");
  cubeShaderProgram_.disableAttributeArray("cube_label");

  cubeShaderProgram_.release();

除了我上面的主要问题(颜色问题),这是一个做Minecraft的好方法吗？

更新
如果我将我的CubeInfo.labelId属性从int更改为float,并且相应的顶点着色器变量cube_label也可以浮动,那么它就是!!为什么会这样？ This page说GLSL支持int类型.对我来说,我更喜欢labelId / cube_label为一些int / short.

UPDATE2：

即使我只是在渲染代码的下一行中更改为GL_FLOAT而不是GL_INT,我也会获得正确的颜色.

cubeShaderProgram_.setAttributeBuffer("cube_label", GL_INT, offsetof(CubeInfo,labelId), 1, sizeof(CubeInfo));

最佳答案 label属性的问题是,它是一个整数属性,但不要将其设置为整数属性. Qt的setAttributeBuffer函数对整数属性一无所知,它们都在引擎盖下使用
glVertexAttribPointer,它以任意格式获取顶点数据并将其转换为float以将其传递给in float属性,该属性与in不匹配来自着色器的int(因此该属性可能只保留一些随机默认值,或获取一些未定义的值).

要实际将数据传递到实际的整数顶点属性(这与float属性完全不同,直到GL 3才会引入),您需要函数glVertexAttribIPointer(注意我在那里,类似D在double属性中,只使用GL_DOUBLE在这种情况下也不起作用).但令人遗憾的是,Qt还没有真正适合GL 3,似乎没有一个包装器.所以你要么必须手动使用：

glVertexAttribIPointer(cubeShaderProgram_.attributeLocation("cube_label"), 
                       1, GL_INT, sizeof(CubeInfo), 
                       static_cast<const char*>(0)+offsetof(CubeInfo,labelId));

而不是使用cubeShaderProgram_.setAttributeBuffer调用,而是使用in float属性.

点赞