prolog – 3-in-a-row逻辑谜题:列表/数组中序列约束的优化

在下面的谜题中,我们尝试用蓝色和白色方块填充网格,使得:

>不允许使用相同颜色的3-in-row(或列).
>每行和每列具有相同数量的蓝色和白色方块.

《prolog – 3-in-a-row逻辑谜题:列表/数组中序列约束的优化》

如果我们现在用0表示白色,用1表示蓝色,我们得到:

0 _ _ _ 1 _
_ 0 _ _ _ _
_ _ _ _ _ 0
1 _ _ 0 _ _
_ _ 1 1 _ _
_ 0 _ _ 1 _

我们可以很快验证这一点

0 1 0 0 1 1 
0 0 1 1 0 1 
1 1 0 1 0 0 
1 1 0 0 1 0 
0 0 1 1 0 1 
1 0 1 0 1 0 

是这个例子的解决方案.

作为约束,我写了以下内容:

constraints(Board,N) :-
    N2 is N // 2,
    ( for(I,1,N), param(Board,N2,N)
    do
      Row is Board[I,1..N],
      Col is Board[1..N,I],
      ic_global:sequence_total(N2,N2,1,2,3,Row),
      ic_global:sequence_total(N2,N2,1,2,3,Col)
    ).

sequence_total/6确保值1应该在行/列中正好出现N2次(N次的一半),并且指定的3个元素的行/列中的每个序列应该包含值1的1到2倍(所以没有值为1的3个正方形可以彼此相邻出现).

我得到了18×18拼图实例(*)的以下结果:

Solved in 147 backtracks
Yes (10.39s cpu, solution 1)

看起来约束在执行任何搜索之前都很好地完成了它们的工作,因为“仅”需要147次回溯.然而,运行时间对我来说似乎很长,特别是与回溯的数量相比.我猜这是由于必须进行的所有序列检查?改变search/6中的任何选择/选择方法几乎没有对运行时间产生任何影响的事实似乎证实了这一点.

如果是这样,是否有任何其他更有效的方法来限制列表/数组中的序列,以使N个相同的元素彼此相邻并改善运行时间?

编辑

使用下面@jschimpf提供的分解版本后,获得以下结果:

Solved in 310 backtracks
Yes (0.22s cpu, solution 1)

新的约束不如sequence / 6强,我们确实需要更多的回溯,但是我们的运行时间从10.39secs下降到0.22secs,所以总体结果是非常理想的.

样本数据:

拼图用于这个问题(解决没有回溯)

problem(p(6,1),[(1,1,0),(1,5,1),(2,2,0),(3,6,0),(4,1,1),(4,4,0),(5,3,1),(5,4,1),(6,2,0),(6,5,1)]).

拼图(*)我发布了我的结果:

problem(p(18,1),[(1,3,0),(1,9,0),(1,10,0),(1,12,0),(1,14,0),(1,18,1),(2,4,0),(2,7,1),(2,8,1),(3,2,1),(3,6,0),(3,16,0),(3,17,0),(4,2,1),(4,4,1),(4,10,1),(4,13,1),(4,18,1),(5,8,1),(5,10,1),(5,15,0),(5,16,1),(6,12,1),(7,3,0),(7,4,0),(7,6,1),(7,9,0),(7,12,1),(7,17,0),(8,1,1),(8,4,0),(8,8,1),(8,15,1),(8,16,1),(9,7,0),(9,10,0),(9,14,0),(10,2,1),(10,4,1),(10,6,1),(10,13,1),(11,7,0),(11,10,1),(12,1,1),(12,4,1),(12,7,1),(12,15,1),(12,16,1),(13,1,1),(13,6,0),(13,8,1),(13,10,0),(13,16,1),(14,5,1),(14,10,0),(14,13,1),(15,1,1),(15,3,1),(15,12,0),(15,13,1),(15,15,0),(16,2,1),(16,4,0),(16,12,0),(16,18,0),(17,9,0),(17,15,0),(17,18,0),(18,2,1),(18,8,1),(18,11,1),(18,15,1),(18,16,1)]).

最佳答案 事实证明,在这种情况下,序列约束的手工制作,分解版本更有效.用例如

sequence_1_2([X1,X2,X3|Xs]) :- !,
    S #:: 1..2,
    X1+X2+X3 #= S,
    sequence_1_2([X2,X3|Xs]).
sequence_1_2(_).

它将任何3元素子序列的总和约束为1或2,并用sequence替换sequence_total / 6约束

    ...,
    sum(Row) #= N2,
    sequence_1_2(Row),

这使得解决时间缩短到0.2秒.

点赞