Android Gradle 多维度实例

前言

上一篇文章Just Enough Gradle for Android介绍了Gradle的一些基本知识,基本概念,理解这些有助于我们更加合理地使用Gradle。这篇文章聚焦于Gradle在Android项目中的实际使用。之所以叫做多维度实例,是想展示Gradle运用的灵活性,对于同一种需求,尽可能尝试用多种方式去实现。比较各种实现之间的思路、方式及优劣。

Android Studio把一个项目/工程称为一个Project,每个Project包含有若干个模块,称为module。在Gradle中,每个build.gradle文件都会生成一个Project对象,顶层build.gradle生成的Project称为RootProject,各个module中的build.gradle生成的Project的称为SubProject。为避免混淆,这篇文章提到的Project都是指Gradle中的Project。

1.区分debug和release

Gradle的Android插件默认定义了两种BuildTypes:debug和release。我们往往需要对这两种BuildTypes进行区分。

1.1 定义不同的applicationId

为了使debug版本和release版本的APP能同时装到手机上,它们需要有不同的applicationId。

android {
    //...
    defaultConfig {
        applicationId "com.example.app"
        //...
    }
    
    buildTypes {
        debug {
            //applicationId的后缀
            applicationIdSuffix '.debug'
            //或者直接指定applicationId
            //applicationId "com.example.app.debug"
            //还可以设置不同的versionName
            versionNameSuffix '-debug'
        }
    }
}

BuildType和ProductFlavor都可以设置自己的applicationId、minSdkVersion、targetSdkVersion、versionName等,如果没有设置,则使用defaultConfig中的设置。

1.2 定义不同的APP名称

如今debug版和release版的APP都装到我们的手机里了,但是它们俩看上去长得一模一样,无论是应用图标还是名称都一样,实在不容易区分。给不同版本的APP起不一样的名字也许是最简单明了的区分方式了。
之所以有不同的BuildType就是为了可以对它们进行差异化设置。Android资源(即res文件下面的内容)的差异化设置非常简单。在与main平级的目录下增加debug文件夹,在相应的资源文件夹下设置app_name即可:

《Android Gradle 多维度实例》 增加debug资源

我们甚至可以为不同版本的APP设置不一样的应用图标(以及其它一切资源),步骤跟修改app_name是一样的,把图标放置在相应文件夹里即可。如果仅仅是为了区分debug版和release版的话,确实没必要。不过对于不同的ProductFlavor还是有用的,的确不同的ProductFlavor可能会用不同的应用图标。一般而言,BuildType主要是内部使用,如debug或者测试什么的;而ProductFlavor主要是外部使用,发布不同版本的APP,如免费版和付费版等。

APP中的资源是互相覆盖的关系:BuildType的优先级最高,然后是ProductFlavor,最后才是main文件夹。BuildType覆盖ProductFlavor的资源,ProductFlavor的资源覆盖main文件夹下的资源。

其实,在build.gradle中可以直接定义资源,跟我们在res/values中定义是一样的:

android {
    buildTypes {
        debug {
            resValue "string", "app_name", "Example DEBUG"
        }
        release {
            resValue "string", "app_name", "Example"
        }
    }
}

1.3 定义不同URL

debug和release版的APP,一般需要设置不同的接口地址,方便测试使用。我们可以使用如下的方式实现:

fun provideRetrofit(client: OkHttpClient): Retrofit {
        //根据是否是DEBUG设置不同的URL
        val url = if (BuildConfig.DEBUG)
            BASE_DEBUG_URL
        else
            BASE_URL
        return Retrofit.Builder()
                .baseUrl(url)
                .client(client)
                .addCallAdapterFactory(RxJava2CallAdapterFactory.create())
                .addConverterFactory(GsonConverterFactory.create())
                .build()
    }

BuildConfig类是项目构建过程中生成的,默认情况下DEBUG只在BuildType为debug的时候为true,其它情况下都为false。当然也可以设置:

android {
    //...
    
    buildTypes {
        debug {
            debuggable = true
        }
    }
}

我们通过BuildConfig的DEBUG字段去决定使用哪个URL,能不能在BuildConfig中增加字段呢?例如直接增加一个BASE_URL字段,这样岂不是更加直接。当然可以:

android {
    //...
    
    buildTypes {
        debug {
            buildConfigField "String", "BASE_URL", '"http://example.com/debugapi"'
        }
        
        release {
            buildConfigField "String", "BASE_URL", '"http://example.com/api"'
            //使用双引号定义字符串则需要转义
            buildConfigField "String", "BASE_URL", "\"http://example.com/api\""
            }
    }
}

利用buildConfigField方法定义新的字段,注意最后一个参数的写法'”http://example.com/api“‘,buildConfigField的三个参数都是String类型,最后一个参数String的值会直接拿来赋值给我们定义的字段:

public final class BuildConfig {
    public static final String BASE_URL = "http://example.com/api";
}

一顿操作之后,我们便可以直接引用我们定义的字段了:

fun provideRetrofit(client: OkHttpClient): Retrofit {
        return Retrofit.Builder()
                .baseUrl(BuildConfig.BASE_URL)
                .client(client)
                .addCallAdapterFactory(RxJava2CallAdapterFactory.create())
                .addConverterFactory(GsonConverterFactory.create())
                .build()
    }

这种方式比较直接,但是如果要修改BASE_URL的值则需要Sync Gradle。究竟使用哪种方式,看你的喜好了。

2.添加额外属性

对于multiproject多工程(包含有多个module)而言,一个常见的需求就是在不同的Project之间“共享”一些属性。例如,指定统一的compileSdkVersion、buildToolsVersion、appcompat版本等。这可以通过额外属性来实现。

2.1 在gradle.properties中添加属性

这种方式的确可以,但是并不推荐。因为gradle.properties主要是用来设置Gradle本身的属性的。

2.2 在顶层的build.gradle中增加额外属性

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.2'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }
}

ext {
    minSdk = 17
    targetSdk = 27
    supportVersion = '27.1.1'
}

这样就可以在所有build.gradle中直接使用额外属性了:

apply plugin: 'com.android.application'

android {
    
    defaultConfig {
        minSdkVersion minSdk
        targetSdkVersion targetSdk
    }
    
    dependencies {
        implementation "com.android.support:appcompat-v7:$supportVersion"
    }
}

注意:我们是在顶层build.gradle中定义的额外属性,它被定义在了RootProject对象中,所有SubProject“继承”了这些属性,因此可以直接访问。如果在module的build.gradle中定义了同名的属性,那么它会覆盖RootProject中相应的属性。

2.3 通过脚本插件定义额外属性

插件对于Gradle而言是极其重要的,除了我们常用的Android Application插件和Android Library插件外,我们也可以自己定义插件。Gradle插件既可以是像Android Application这样的,实现了Plugin接口的插件(主要用来定义了Tasks,在多个Project中复用这些Tasks);也可以是简单的groovy脚本文件(主要用来在多个Project中共享一些属性、方法等)。根据我们的需求,定义脚本插件即可。
可以在根目录定义versions.gradle文件:

ext {
    minSdk= 17
    targetSdk= 27
    compileSdk= 27
    buildTools= '27.0.3'
    supportVersion = '27.1.1'
}

然后在顶层build.gradle中将versions.gradle作为脚本插件,应用到所有Project中:

buildscript {
    //写在这里也可以
    //apply from: 'versions.gradle'
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.1.2'
    }
}

allprojects {
    apply from: 'versions.gradle'
    repositories {
        google()
        jcenter()
    }
}

余下的步骤是一样的,可以在所有build.gradle中直接使用额外属性了。这种方式不同于在RootProject中定义额外属性,versions.gradle被应用在了所有的Project中,相当于在每个Project中都定义了额外属性,只是这些属性都是相同的。并且,这种方式也更加符合Gradle模块化的思想,是比较推荐的方式。
进一步的,我们可以在versions.gralde中定义更多东西:

//定义扩展属性deps,deps的类型是Map,[:]是groovy声明 Map的方式
ext.deps = [:]

//定义各种依赖库的版本
def versions = [:]
versions.support = "27.1.1"
//...

def deps = [:]
def support = [:]
support.annotations = "com.android.support:support-annotations:$versions.support"
support.app_compat = "com.android.support:appcompat-v7:$versions.support"
support.recyclerview = "com.android.support:recyclerview-v7:$versions.support"
support.cardview = "com.android.support:cardview-v7:$versions.support"
support.design = "com.android.support:design:$versions.support"
support.v4 = "com.android.support:support-v4:$versions.support"
support.core_utils = "com.android.support:support-core-utils:$versions.support"
deps.support = support

//把deps变量赋值给扩展属性deps
ext.deps = deps

def build_versions = [:]
build_versions.min_sdk = 14
build_versions.target_sdk = 27
build_versions.build_tools = "27.0.3"
ext.build_versions = build_versions

在module中的build.gradle中:

apply plugin: 'com.android.application'

android {
    compileSdkVersion build_versions.target_sdk
    buildToolsVersion build_versions.build_tools
    //...
}

dependencies {
    //扩展属性deps是一个 Map,这样便于对依赖进行分组管理
    implementation deps.support.app_compat
    implementation deps.support.recyclerview
    implementation deps.support.cardview
    implementation deps.support.design
    //...
}

尾巴

我自己对Gradle的使用也比较有限,遇到更多Gradle的使用实例我再补充。

    原文作者:珞泽珈群
    原文地址: https://www.jianshu.com/p/4b67931faddf
    本文转自网络文章,转载此文章仅为分享知识,如有侵权,请联系博主进行删除。
点赞